Memorizzare i click sui link

Occorre una tabella: 

IDlink Contatore PK
url    Testo (255)
click  Numerico
Popoliamo la tabella con i nostri link e creiamo lo script links.asp che legge gli URL e costruisce una pagina con l'elenco cliccabile. 

<%
Dim objConn, objRS, SQL
 
'apriamo la connessione
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & _
             Server.MapPath("/mdb-database/links")
 
'impostiamo la query per estrarre i link dal db
SQL = "SELECT * FROM links"
 
'eseguiamo la query
Set objRS = objConn.Execute(SQL)
 
'se il nostro recordset contiene record
'generiamo l'output per il browers con
'l'elenco dei link, i vari link puntano
'alla pagina click.asp che esegue l'aggiornamento
'del conteggio dei click e ridireziona il browser
'al link prescelto
If Not objRS.EOF Then
  Response.Write "<table border=""0"">"
  Response.Write "<tr><td>Link</td>"
  Response.Write "<td>Click</td></tr>"
  Do While Not objRS.EOF
    Response.Write "<tr><td>"
    Response.Write "<a href=""click.asp?ID="
    Response.Write objRS("IDlink")
    Response.Write """>"
    Response.Write objRS("url")
    Response.Write "</a></td><td>"
    Response.Write objRS("click")
    Response.Write "</td></tr>"
    objRS.MoveNext
  Loop
  Response.Write "</table>"
Else
  Response.Write "Non ci sono link"
End If
 
'liberiamo memoria
Set objRS = Nothing
objConn.Close
Set objConn = Nothing
%>
e lo script click.asp, che effettua l'aggiornamento dei click sul db e lancia illink selezionato 

<%
Dim objConn, objRS, ID, url
 
'recuperiamo l'ID tramesso dalla pagina links.asp
ID = Request.QueryString("ID")
 
'verifichiamo che l'ID sia valido altrimenti si torna
'alla links.asp, potremmo verificare se l'ID esista realmente
'ma questo lo lascio a voi
If ID <> "" AND IsNumeric(ID) Then
  'impostiamo la query di aggiornamento dei click
  SQL = "UPDATE links SET click = click + 1 WHERE IDlink = " & ID
 
  'apriamo il database
  Set objConn = Server.CreateObject("ADODB.Connection")
  objConn.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & _
               Server.MapPath("/mdb-database/links")
 
  'eseguiamo la query di aggiornamento
  objConn.Execute(SQL)
  
  'impostiamo la query per recuperare il link scelto
  SQL = "SELECT url FROM links WHERE IDlink = " & ID
 
  'eseguiamo la query
  Set objRS = objConn.Execute(SQL)
 
  'memorizziamo l'indirizzo recuperato
  url = objRS("url")
 
  'liberiamo memoria
  Set objRS = Nothing
  objConn.Close
  Set objConn = Nothing
  
  'reindiriziamo il browser al link scelto
  Response.Redirect(url)
 
End If
 
Response.Redirect("links.asp")
%>